# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# $Id: 6785fe0dffa3c32e1038e926075064ee67f4a472 $

EAPI=8

inherit cmake flag-o-matic plocale xdg poly-c_ebuilds

#PLOCALES="ca_ES cs_CZ de_DE es_AR es_ES es_MX et_EE fi_FI fr_FR hu_HU id_ID it_IT ja_JP ko_KR nb_NO nl_NL pl_PL pt_BR ru_RU sv_SE tr_CY tr_TR uk_UA zh_CN zh_TW"
PLOCALES="*"

DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
HOMEPAGE="https://www.strawberrymusicplayer.org/"
if [[ ${MY_PV} == *9999* ]]; then
	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
	inherit git-r3
else
	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${MY_PV/_/-}/${MY_P/_}.tar.xz"
	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
	S="${WORKDIR}/${MY_P/_}"
fi

LICENSE="GPL-3"
SLOT="0"
IUSE="cdda debug ipod moodbar mtp pulseaudio soup +udisks"

BDEPEND="
	sys-devel/gettext
	virtual/pkgconfig
"
COMMON_DEPEND="
	dev-db/sqlite:=
	dev-cpp/abseil-cpp:=
	dev-libs/glib:2
	dev-libs/icu:=
	dev-libs/kdsingleapplication[qt6(+)]
	dev-libs/protobuf:=
	dev-qt/qtbase:6[concurrent,dbus,gui,network,ssl,sql,sqlite,widgets]
	media-libs/alsa-lib
	media-libs/chromaprint:=
	media-libs/gstreamer:1.0
	media-libs/gst-plugins-base:1.0
	media-libs/taglib:=
	cdda? ( dev-libs/libcdio:= )
	ipod? ( media-libs/libgpod )
	moodbar? ( sci-libs/fftw:3.0 )
	mtp? ( media-libs/libmtp )
	pulseaudio? ( media-libs/libpulse )
"
# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
RDEPEND="${COMMON_DEPEND}
	media-plugins/gst-plugins-meta:1.0
	media-plugins/gst-plugins-taglib:1.0
	soup? ( media-plugins/gst-plugins-soup:1.0 )
	mtp? ( gnome-base/gvfs[mtp] )
	udisks? ( sys-fs/udisks:2 )
"
DEPEND="${COMMON_DEPEND}
	dev-cpp/gtest
	dev-libs/boost
"

DOCS=( Changelog README.md )

src_prepare() {
	plocale_find_changes "src/translations" "" ".po"

	cmake_src_prepare
}

src_configure() {
	# spotify is not in portage
	local mycmakeargs=(
		-DBUILD_WERROR=OFF
		# avoid automagically enabling of ccache (bug #611010)
		-DCCACHE_EXECUTABLE=OFF
		-DENABLE_GIO=ON
		-DLINGUAS="$(plocale_get_locales)"
		-DENABLE_AUDIOCD="$(usex cdda)"
		-DENABLE_LIBGPOD="$(usex ipod)"
		-DENABLE_LIBMTP="$(usex mtp)"
		-DENABLE_LIBPULSE="$(usex pulseaudio)"
		-DENABLE_MOODBAR="$(usex moodbar)"
		-DENABLE_MUSICBRAINZ=ON
		-DENABLE_SONGFINGERPRINTING=ON
		-DENABLE_SPOTIFY=ON
		-DENABLE_UDISKS2="$(usex udisks)"
	)

	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT

	cmake_src_configure
}

pkg_postinst() {
	xdg_pkg_postinst

	elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
	elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
	elog "depending on your preferences"
}